- N +

定时自动备份文件BAT批处理脚本(添加到系统任务执行)

文章目录 [+]

定时自动备份文件BAT批处理脚本(添加到系统任务执行)-郧阳涛哥博客

郧阳涛哥近日在做服务数据备份的时候,感觉部分资料来回进行手动备份,确实有些不便与麻烦,通过查询相关资料与询问相关“砖家”得到以下样本供大家参考使用。请将下面带有颜色部分批处理脚本代码复制到文本文档,然后另存为诸如“郧阳涛哥定时自动备份文件BAT批处理脚本(添加到系统任务执行).bat”即可。切记:红色部分要改成自己所需要备份的文件路径与备份文件的目标路径哦。


@echo off

rem echo 命令窗口字体颜色与清屏

color 0b & cls

echo;

title 定时自动备份文件BAT批处理脚本(添加到系统任务执行)

echo;程序初始化完成,正在进行压缩处理,请稍候...

echo;

cd /d "%~dp0"

rem echo 压缩程序所在安装位置决对路径

set "压缩程序=C:\Program Files\WinRAR_V5.61\WinRAR.exe"

rem echo 指定要备份的文件夹

set "备份目录=D:\Screenshot"

rem echo 备份文件所在存放位置 

set "存放目录=E:\Backup"

rem echo 程序初始化开始...

if not exist "%压缩程序%" (echo;"%压缩程序%" not found&goto end)

if not exist "%备份目录%" (echo;"%备份目录%" not found&goto end)

if not exist "%存放目录%" (md "%存放目录%")

rem echo 获取本地当前系统日期与系统时间

for /f "tokens=2 delims==" %%a in ('wmic OS get LocalDateTime /value ^|find "="') do set d=%%a

rem echo 去掉1点到9点前的空格,并将空格替换为0。

set h=%time:~0,2%

set h=%h: =0%

rem echo 命名规则(年月日_时分秒)

set today=%d:~0,4%%d:~4,2%%d:~6,2%_%h%%time:~3,2%%time:~6,2%

rem echo 正式生成文件名,并输出到屏幕窗口。

echo;压缩文件名称:%today%.Zip

rem echo 执行上述规则,并开始压缩文件。

rem echo a添加文件,-afzip压缩为zip格式(仅限WinRAR),-r递归,-ed不添加空目录,-ep1从名称中排除基本目录,命令行rar.exe程序无法压缩为zip文件。

"%压缩程序%" a -afzip -r -ed -ep1 "%存放目录%\%today%.zip" "%备份目录%\*"

:end

echo;

rem echo 文件压缩执行完成,并输出到屏幕窗口。

echo;文件压缩处理完成,请到文件备份目录查看。

echo;

rem echo 按任意键退出当前命令窗口。

pause

有好的文章希望郧阳涛哥帮助分享或推广,请猛戳我要投稿图标。我要投稿

0

0
返回列表
上一篇:
下一篇:

发表评论中国互联网举报中心

快捷回复:

    评论列表 (暂无评论,共139人参与)参与讨论

    还没有评论,来说两句吧...